BEGIN PGM ORIENT MM
*** ProbeNr != 0 ***
FN 18: SYSREAD QL0 = ID 350 NR 50 IDX 2
FN 9: IF +QL0 EQU +0 GOTO LBL "END"
*** CfgProbeTool-orientProperty != NoneOrient(0) ***
QS0 = SYSSTR( ID 10350 NR 50 )              ; Tastertyp
QS1 = "CfgProbeTool"
QS2 = "orientProperty"
QL0 = CFGREAD( KEY_ QS0 TAG_ QS1 ATR_ QS2 )
FN 9: IF +QL0 EQU +0 GOTO LBL "END"
*** TRACKING == 1 ***
FN 18: SYSREAD QL0 = ID 350 NR 57 IDX 1     ; TRACKING
FN 10: IF +QL0 NE +1 GOTO LBL "END"
*** mStrobePos == -1 ***
QL0 = 0                                     ; Initialisierung
QS0 = "CH_NC"
QS1 = "CfgActivateKinem"
QS2 = "kinemToActivate"
QS0 = CFGREAD( KEY_ QS0 TAG_ QS1 ATR_ QS2 IDX0 )
QS1 = "CfgKinComposModel"
QS2 = "activeSpindle"
FN 17: SYSWRITE ID 13 NR 3 = 9999           ; Label bei SQL-Fehler
QS0 = CFGREAD( KEY_ QS0 TAG_ QS1 ATR_ QS2 IDX0 )
QS1 = "CfgTS"
QS2 = "mStrobePos"
QL0 = CFGREAD( KEY_ QS0 TAG_ QS1 ATR_ QS2 IDX0 )
LBL 9999
FN 10: IF +QL0 NE -1 GOTO LBL "END"
*** NC uebernimmt Spindelkontrolle ***
FN 17: SYSWRITE ID 990 NR16 =+1             ; Spindelkontrolle ein
LBL "END"
END PGM ORIENT MM 
