BEGIN PGM 402 MM
CALL PGM CHECK_BAMODE.CYC
FN 9: IF +Q169 EQU +1.1 GOTO LBL 254
Q198 = 402
CALL PGM ORIENT.CYC
FN 9: IF +Q402 EQU +0 GOTO LBL 10
FN 18: SYSREAD Q51 = ID210 NR6
FN 10: IF +Q51 NE -1 GOTO LBL 10
FN 14: ERROR= 1075
LBL 10
CALL PGM INIT.CYC
Q320 = Q320 + Q2 + Q3
Q19 = ( Q313 / 2 ) + Q320
Q20 = ( Q314 / 2 ) + Q320
Q62 = Q315 - Q2
; ** 1. Zapfen *************
FN 12: IF +Q261 LT +Q260 GOTO LBL 130
FN 14: ERROR= 1016
LBL 130
FN 1: Q1 =+Q109 + +1
FN 18: SYSREAD Q0 = ID270 NR1 IDXQ1
FN 11: IF +Q0 GT +Q260 GOTO LBL 120
L  Z+Q260 R0 FQ59
LBL 120
CC  X+Q268  Y+Q269
LP  PR+Q19  PA+0 R0 FQ59
TCH PROBE 0.0 BEZUGSEBENE Q0 X-
TCH PROBE 0.1  Z+Q261
CALL PGM READ_RESULT.CYC
FN 0: Q1 =+Q141
FN 0: Q2 =+Q142
FN 9: IF +Q301 EQU +0 GOTO LBL 20
L  Z+Q260 R0 FQ59
LBL 20
CP IPA+90 DR+ R0 FQ59
TCH PROBE 0.0 BEZUGSEBENE Q0 Y-
TCH PROBE 0.1  Z+Q261
CALL PGM READ_RESULT.CYC
FN 0: Q3 =+Q141
FN 0: Q4 =+Q142
FN 9: IF +Q301 EQU +0 GOTO LBL 21
L  Z+Q260 R0 FQ59
LBL 21
CP IPA+90 DR+ R0 FQ59
TCH PROBE 0.0 BEZUGSEBENE Q0 X+
TCH PROBE 0.1  Z+Q261
CALL PGM READ_RESULT.CYC
FN 0: Q5 =+Q141
FN 0: Q6 =+Q142
FN 9: IF +Q301 EQU +0 GOTO LBL 22
L  Z+Q260 R0 FQ59
LBL 22
CP IPA+90 DR+ R0 FQ59
TCH PROBE 0.0 BEZUGSEBENE Q0 Y+
TCH PROBE 0.1  Z+Q261
CALL PGM READ_RESULT.CYC
FN 0: Q7 =+Q141
FN 0: Q8 =+Q142
L  Z+Q260 R0 FQ59
; ** 2. Zapfen ***************
CC  X+Q270  Y+Q271
LP  PR+Q20  PA+0 R0 FQ59
TCH PROBE 0.0 BEZUGSEBENE Q0 X-
TCH PROBE 0.1  Z+Q261
CALL PGM READ_RESULT.CYC
FN 0: Q11 =+Q141
FN 0: Q12 =+Q142
FN 9: IF +Q301 EQU +0 GOTO LBL 23
L  Z+Q260 R0 FQ59
LBL 23
CP IPA+90 DR+ R0 FQ59
TCH PROBE 0.0 BEZUGSEBENE Q0 Y-
TCH PROBE 0.1  Z+Q261
CALL PGM READ_RESULT.CYC
FN 0: Q13 =+Q141
FN 0: Q14 =+Q142
FN 9: IF +Q301 EQU +0 GOTO LBL 24
L  Z+Q260 R0 FQ59
LBL 24
CP IPA+90 DR+ R0 FQ59
TCH PROBE 0.0 BEZUGSEBENE Q0 X+
TCH PROBE 0.1  Z+Q261
CALL PGM READ_RESULT.CYC
FN 0: Q15 =+Q141
FN 0: Q16 =+Q142
FN 9: IF +Q301 EQU +0 GOTO LBL 25
L  Z+Q260 R0 FQ59
LBL 25
CP IPA+90 DR+ R0 FQ59
TCH PROBE 0.0 BEZUGSEBENE Q0 Y+
TCH PROBE 0.1  Z+Q261
CALL PGM READ_RESULT.CYC
FN 0: Q17 =+Q141
FN 0: Q18 =+Q142
L  Z+Q260 R0 FQ59
FN 24: Q21 = CDATA Q1
FN 24: Q31 = CDATA Q11
FN 2: Q41 =+Q31 - +Q21
FN 2: Q42 =+Q32 - +Q22
FN 13: Q50 =+Q42 ANG +Q41
FN 12: IF +Q50 LT +90 GOTO LBL 31
FN 9: IF +Q50 EQU +90 GOTO LBL 31
FN 11: IF +Q50 GT +270 GOTO LBL 30
FN 9: IF +Q50 EQU +270 GOTO LBL 30
Q50 = Q50 - 180
FN 9: IF +0 EQU +0 GOTO LBL 31
LBL 30
Q50 = Q50 - 360
LBL 31
Q50 = Q50 - Q307
CALL PGM CALC_ANGLE.CYC
FN 10: IF +Q402 NE +1 GOTO LBL 100
CALL PGM AXISCOMP.CYC
FN 9: IF +0 EQU +0 GOTO LBL 252
LBL 100
CALL PGM WRITE_BROT.CYC
LBL 252
FN 17: SYSWRITE ID 990 NR1 =+0
FN 17: SYSWRITE ID 990 NR2 =+0
LBL 254
FN 17: SYSWRITE ID 990 NR16 =+0 ;# Spindelkontrolle aus
END PGM 402 MM
