BEGIN PGM 409 MM 
FN 18: SYSREAD Q0 = ID2000 NR10 IDX4158
FN 9: IF +Q0 EQU +1 GOTO LBL 254
FN 18: SYSREAD Q0 = ID990 NR2 IDX16
FN 9: IF +Q0 EQU +0 GOTO LBL 254
CALL PGM CHECK_MP7295_CYC419.CYC
Q198 = 409
FN 10: IF +Q303 NE +1 GOTO LBL 10
CALL PGM INIT41X.CYC
LBL 10
CALL PGM INIT.CYC
;** Nur WZ-Achse X, Y, Z erlaubt
FN 12: IF +Q109 LT +3 GOTO LBL 2
FN 14: ERROR= 1079
LBL 2
Q19 = Q320
Q320 = Q320 + Q2 + Q3
Q10 = 180 + Q41
Q42 = Q2
FN 12: IF +Q261 LT +Q260 GOTO LBL 119
FN 14: ERROR= 1016
LBL 119
FN 1: Q1 =+Q109 + +1
FN 18: SYSREAD Q0 = ID270 NR1 IDXQ1
FN 11: IF +Q0 GT +Q260 GOTO LBL 120
L  Z+Q260 R0 FQ59
LBL 120
FN 9: IF +Q272 EQU +2 GOTO LBL 20
; Antastrichtung X
Q1 = Q321 + ( Q311 / 2 ) + Q320
Q11 = Q321 - ( Q311 / 2 ) - Q320
L  X+Q1  Y+Q322 R0 FQ59
TCH PROBE 1.0 BEZUGSPUNKT POLAR
TCH PROBE 1.1 X WINKEL:+Q10
TCH PROBE 1.2  Z+Q261
CALL PGM SUB_POSREAD.CYC
Q5 = Q141
Q10 = Q41
L  Z+Q260 FQ59
L  X+Q11  Y+Q322 FQ59
TCH PROBE 1.0 BEZUGSPUNKT POLAR
TCH PROBE 1.1 X WINKEL:+Q10
TCH PROBE 1.2  Z+Q261
CALL PGM SUB_POSREAD.CYC
Q6 = Q141
Q31 = ABS ( Q5 - Q6 - ( 2 * Q2 ) ) ; Istbreite
Q141 = Q5 - ( Q31 / 2 ) - ABS Q2
Q142 = Q322
Q157 = Q141
Q166 = Q31
FN 9: IF +0 EQU +0 GOTO LBL 253
LBL 20
; Antastrichtung Y
Q3 = Q322 + ( Q311 / 2 ) + Q320
Q4 = Q322 - ( Q311 / 2 ) - Q320
Q10 = 270 + Q41
L  X+Q321  Y+Q3 FQ59
TCH PROBE 1.0 BEZUGSPUNKT POLAR
TCH PROBE 1.1 X WINKEL:+Q10
TCH PROBE 1.2  Z+Q261
CALL PGM SUB_POSREAD.CYC
Q5 = Q142
Q10 = 90 + Q41
L  Z+Q260 FQ59
L  X+Q321  Y+Q4 FQ59
TCH PROBE 1.0 BEZUGSPUNKT POLAR
TCH PROBE 1.1 X WINKEL:+Q10
TCH PROBE 1.2  Z+Q261
CALL PGM SUB_POSREAD.CYC
Q6 = Q142
Q32 = ABS ( Q5 - Q6 - ( 2 * Q2 ) ) ;Istbreite
Q142 = Q5 - ( Q32 / 2 ) - ABS Q2
Q141 = Q321 ; ggf. BZPKT X
Q157 = Q142
Q166 = Q32
LBL 253
L  Z+Q260 FQ59
CALL PGM PRESET_40X.CYC
FN 17: SYSWRITE ID 990 NR1 =+0
FN 17: SYSWRITE ID 990 NR2 =+0
LBL 254
FN 9: IF +Q381 EQU +0 GOTO LBL 255
TCH PROBE 417 BZPKT TS.-ACHSE ~
Q263=+Q382 ;1. PUNKT 1. ACHSE ~
Q264=+Q383 ;1. PUNKT 2. ACHSE ~
Q294=+Q384 ;1. PUNKT 3. ACHSE ~
Q320=+Q19 ;SICHERHEITS-ABST. ~
Q260=+Q260 ;SICHERE HOEHE ~
Q305=+Q305 ;NR. IN TABELLE ~
Q333=+Q333 ;BEZUGSPUNKT ~
Q303=+Q303 ;MESSWERT-UEBERGABE
LBL 255
Q199 = 0
END PGM 409 MM 
